在Arduino中字符串一般用于存儲文本，類似于在LCD或Arduino IDE串口監(jiān)視器窗口中顯示的文本信息。字符串也可用于存儲用戶的輸入，例如，存儲用戶在連接Arduino的鍵盤上鍵入的某些字符。 Arduino程序中包含兩種類型的字符串：

1. 字符型數(shù)組，與C語言中使用的字符串相同。
2. Arduino字符串，它允許我們在 sketch 中使用 String 對象。

在本章中，我們將學(xué)習(xí)字符串、對象以及Arduino sketch 中字符串的使用。在最后，將介紹在 sketch 中都包含哪種類型的字符串。

 

字符串和字符數(shù)組

字符串是 char 類型的一系列字符。字符數(shù)組是存儲在內(nèi)存中的同一類型變量的連續(xù)序列。字符數(shù)組就是多個 char 變量字符組成的數(shù)組。字符數(shù)組末尾包含有一個額外特殊的 0 值元素的字符，就是所謂的“空結(jié)尾字符串”。

字符串和字符數(shù)組示例

字符串示例：創(chuàng)建字符串并將其打印到串口監(jiān)視器窗口。

void setup() {
   char my_str[] = "Hello";
   Serial.begin(9600);
   Serial.println(my_str);
}
void loop() {
}

字符數(shù)組示例：下面的例子顯示了字符數(shù)組是由什么組成的：

 void setup() {
   char my_str[6]; // 一個容納5個字符串的數(shù)組
   Serial.begin(9600);
   my_str[0] = 'H'; // 字符數(shù)組由5個字符組成
   my_str[1] = 'e';
   my_str[2] = 'l';
   my_str[3] = 'l';
   my_str[4] = 'o';
   my_str[5] = 0;   //  第6個數(shù)組元素是一個空結(jié)尾字符
   Serial.println(my_str);
}
void loop() { 
}

通過學(xué)習(xí)，我們知道一個字符數(shù)組包含可打印字符串和空結(jié)尾字符 0 ，空結(jié)尾字符表明這是字符數(shù)組結(jié)束的地方。 在程序中，我們可以通過使用Serial.println()傳遞字符數(shù)組的名稱，并將字符數(shù)組打印到Arduino IDE的串口監(jiān)視器窗口中。

字符數(shù)組的修改

下面我們通過具體實例來學(xué)習(xí)，如下所示 ：

void setup() {
   char like[] = "I like coffee and cake"; // 創(chuàng)建一個字符串
   Serial.begin(9600);
   // (1) 輸出字符串
   Serial.println(like);
   // (2) 刪除部分字符串
   like[13] = 0;
   Serial.println(like);
   // (3) 在字符串中替換一個單詞
   like[13] = ' '; // 用空格替換空終止符
   like[18] = 't'; // 插入新單詞
   like[19] = 'e';
   like[20] = 'a';
   like[21] = 0;  // 空結(jié)尾字符
   Serial.println(like);
}
void loop() {
}

串口監(jiān)視器輸出結(jié)果：

I like coffee and cake
I like coffee
I like coffee and tea

代碼工作原理

創(chuàng)建和打印字符串

在上面給出的示例中，首先創(chuàng)建了一個新字符串”I like coffee and cake”，然后在串行監(jiān)視器窗口中顯示 ，見示例中的 （1）。 此處輸出“I like coffee and cake”。

截斷字符串

接著，將字符串中的第14個字符替換為 0 ，見示例中的( 2 ) ，從而達(dá)到截斷字符串的目的。在字符數(shù)組中是從 0 開始順序計數(shù)的，因此第13個元素對應(yīng)字符串第14個字符 。當(dāng)打印字符串時，0 值空結(jié)尾字符之后的字符串將不會被打印出來。此時被截斷的其他字符并不會消失，它們?nèi)匀淮嬖谟趦?nèi)存中，并且字符數(shù)組的大小仍然不變，惟一的區(qū)別是，任何處理字符串的函數(shù)都將只看到第一個空結(jié)尾字符之前的字符串。

在字符串中更改字符

最后，來看看示例中如何將單詞“cake”替換為“tea”(3)。首先必須用“空格”替換數(shù)組[13]的空結(jié)尾字符，這樣可以把字符串恢復(fù)到最初創(chuàng)建的格式。將單詞“cake”的“cak”改寫為單詞“tea”，這是通過直接覆蓋單個字符來實現(xiàn)的，“cake”的“e”被替換為一個新的空結(jié)尾字符 0。最終，新字符串實際上是以兩個空結(jié)尾字符結(jié)束的，一個是字符串末尾的原始字符，另一個是替換“cake”中的“e”的新字符。在打印輸出新字符串時實際上是沒有任何區(qū)別的，因為打印輸出字符串的函數(shù)在遇到第一個空結(jié)尾字符時就停止了。

修改字符數(shù)組的函數(shù)

前面的示例通過訪問字符串中的單個字符達(dá)到手動相修改字符數(shù)組的目的。為了更簡單的修改字符數(shù)組，您可以編寫自己的函數(shù)，或者使用C語言庫中的一些字符串函數(shù)。這些函數(shù)包括： String()、charAt()、compareTo()、concat()、c_str()、endsWith()、equals()、equalsIgnoreCase()、getBytes()、indexOf()、lastIndexOf()、length()、remove()、replace()、reserve()、setCharAt()、startsWith()、toCharArray()、substring()、 toInt()、 toFloat()、toLowerCase()、toUpperCase()、trim()等。

看下面的示例：

void setup() {
   char str[] = "This is my string"; // 創(chuàng)建字符串
   char out_str[40]; // 字符串函數(shù)的輸出
   int num; // 整型數(shù)
   Serial.begin(9600);
   // (1) 打印字符串
   Serial.println(str);
   // (2) 獲取字符串長度(不包括空結(jié)尾字符)
   num = strlen(str);
   Serial.print("String length is: ");
   Serial.println(num);
   // (3) 獲取數(shù)組的長度(包括空結(jié)尾字符)
   num = sizeof(str); // sizeof() is not a C string function
   Serial.print("Size of the array: ");
   Serial.println(num);
   // (4) 復(fù)制字符串
   strcpy(out_str, str);
   Serial.println(out_str);
   // (5) 在字符串的末尾添加一個字符串 (append)
   strcat(out_str, " sketch.");
   Serial.println(out_str);
   num = strlen(out_str);
   Serial.print("String length is: ");
   Serial.println(num);
   num = sizeof(out_str);
   Serial.print("Size of the array out_str[]: ");
   Serial.println(num);
}
void loop() {
}

輸出結(jié)果：

This is my string
String length is: 17
Size of the array: 18
This is my string
This is my string sketch.
String length is: 25
Size of the array out_str[]: 40

工作原理

和上一個示例一樣，首先創(chuàng)建了一個新字符串，然后在串行監(jiān)視器窗口中顯示出來。

獲取字符串的長度， strlen() 函數(shù)的作用是:獲取字符串的長度。字符串的長度只適用于可打印字符，不包括空結(jié)尾字符。該字符串包含17個字符，因此我們在串行監(jiān)視器窗口中看到：“String length is: 17”。

獲取數(shù)組的長度， 利用操作符 sizeof() 獲取字符數(shù)組的長度（包含空結(jié)尾字符），因此字符數(shù)組的長度比字符串的長度多1，“Size of the array: 18”。sizeof() 看起來像一個函數(shù)，但是它是一個操作符，通常用來顯示字符數(shù)組長度和字符串長度之間的差異。

復(fù)制一個字符數(shù)組，strcpy() 函數(shù)的作用是將 str[] 字符數(shù)組復(fù)制到 out_num[] 數(shù)組中。 strcpy() 函數(shù)將傳遞給它的第二個字符串（“str”）復(fù)制到第一個字符串（“out_str”）中。字符串的副本現(xiàn)在存在于 out_num[] 數(shù)組中，但是只占用數(shù)組的18個元素，所以數(shù)組中仍然有22個空閑的 char 元素，這可以在下一步驟使用，也就是在字符串的末尾添加字符串。

將字符串追加到字符串末尾，將一個字符串連接到另一個字符串，這是使用strcat() 函數(shù)來完成的，函數(shù)的作用是: 將傳遞給它的第二個字符串（“ sketch.”）放在傳遞給它的第一個字符串（“out_str”）的末尾。字符串連接之后，打印輸出字符串的長度來顯示新的字符串長度，然后再打印輸出數(shù)組的長度，顯示在一個40個元素的長數(shù)組中有一個25個字符的長字符串。 “String length is: 25”，“ Size of the array out_str[]: 40”。需要注意的是：25個字符的長字符串實際上占用了數(shù)組的26個字符，因為還要包含 0 這個空結(jié)尾字符 。